DIY T12 Soldering Station

This is a part 2 of my soldering station build. Main difference – T12 soldering tips instead of old 900M tips.  T12 tips are superior because they have heating element and temperature sensor embedded directly into the tip itself, giving maximum thermal conductivity and most accurate temperature control. T12 tips also heat up much quicker.

Here you can see the difference between these two types of tips: T12 (top) and 900M (bottom). T12 has connections on the end for heating element and sensor while 900M has a hole where external heating element with sensor is inserted and that gives very poor temperature control due to sensor measuring heater temp instead of the tip.

One challenge with using T12 tips is that they are using thermocouple in series with heater element so you can only measure temperature when heater is off. This requires a bit of additional electronics and high side heater switching. Bellow you can see schematic of the soldering station.

Heater element is switched with Q2 N-channel MOSFET. Since it is in high side configuration, charge pump was added to raise gate above 24V. I could have used just a P-channel MOSFET here, but they are less efficient (probably not a problem here) and I wanted to experiment with charge pumps.

Thermocouple signal is filtered by R2, C2 low pass filter and amplified by LMV358 op-amp (schematic says LM358, but you need LMV358 here due to its rail-to-rail output). D1 5V zener is there to prevent high voltage entering op-amp when the heater is on.

Everything is controlled by Atmega328 MCU. Display is generic Nokia 3310. Temperature is selected with a rotary encoder.

PCBs were manufactured by iTead (10 pcs for 19$). Now you may ask why there are 6 PCBs soldered in the photo above? I spent whole day trying to figure out why none of the boards can be programmed via ISP. Until I tried to desolder working Atmega328 from arduino and place it on my board. Turns out that all 20 atmegas that I got from china were dead. Maybe packaging them in plastic Pro-ESD wrap was not a good idea CHINA. But apparently they still ship most of their chips that way.

Anyway, once everything was working it was time to write simple firmware and calibrate PID controller. I also calibrated temperature sensor by using external thermocouple attached to the tip:

I just manually plotted ADC voltage readings vs external thermocouple readings in Excel and fitted a quadratic curve over the data.

Everything fitted nicely in a 24V power supply brick. It is surprising how they left so much free space inside.

Arduino code:

#include <JC_Button.h>
#include <Event.h>
#include <Timer.h>
#include <PID_v1.h>
#include <SPI.h>
#include <Adafruit_GFX.h>
#include <Adafruit_PCD8544.h>


// Hardware SPI (faster, but must use certain hardware pins):
// SCK is LCD serial clock (SCLK) - this is pin 13 on Arduino Uno
// MOSI is LCD DIN - this is pin 11 on an Arduino Uno
// pin 5 - Data/Command select (D/C)
// pin 4 - LCD chip select (CS)
// pin 3 - LCD reset (RST)
Adafruit_PCD8544 display = Adafruit_PCD8544(7, 6, 5);

bool enabled = true;

//Define Variables we'll be connecting to
double Setpoint, Input, Output;
double CurrentTemp;

//Define the aggressive and conservative Tuning Parameters
double aggKp=20, aggKi=0, aggKd=1;
double consKp=20, consKi=1, consKd=1;

//Specify the links and initial tuning parameters
PID ctrl(&Input, &Output, &Setpoint, aggKp, aggKi, aggKd, DIRECT);

#define TEMP_MIN 100
#define TEMP_MAX 500

// Pins
#define SENSOR_PIN A0
#define CONTROL_PIN 9
#define ROTARY_1_PIN A3
#define ROTARY_2_PIN A4
#define BUTTON_PIN A2
#define LCD_LIGHT_PIN 8

// Rotary encoder
bool lastRot = false;
int8_t accel;

#define PULLUP true
#define INVERT true
#define DEBOUNCE_MS 20
#define LONG_PRESS 1500
Button btn(BUTTON_PIN, DEBOUNCE_MS, PULLUP, INVERT);

// Timer
Timer t;

#define ROTARY_CHECK_INTERVAL 3
int8_t rotaryCheckTimer = NO_TIMER_AVAILABLE;

#define LCD_REDRAW_INTERVAL 100
int8_t LCDRedrawTimer = NO_TIMER_AVAILABLE;

#define PID_UPDATE_INTERVAL 100
int8_t PIDUpdateTimer = NO_TIMER_AVAILABLE;

#define ADC_SAMPLE_INTERVAL 50
int8_t ADCSampleTimer = NO_TIMER_AVAILABLE;

// Fire icon bitmap
static const unsigned char PROGMEM fire_bmp[] =
{ B00000001, B00000000,
  B00000011, B00000000,
  B00000111, B00000000,
  B00000101, B10000000,
  B00000101, B10000000,
  B00000100, B11000000,
  B00010110, B01000000,
  B00010010, B01100000,
  B00111011, B00110000,
  B00101001, B00110000,
  B01101101, B00011000,
  B01100111, B00011000,
  B01000110, B00001100,
  B11000100, B00001100,
  B10000000, B00001100,
  B10000000, B00001100,
  B10000000, B00001100,
  B11000000, B00011000,
  B01110000, B01111000,
  B00111111, B11110000,
  B00001111, B11000000};


void setup() {
  Serial.begin(115200);

  //analogReference(INTERNAL);
  pinMode(SENSOR_PIN, INPUT);
  pinMode(CONTROL_PIN, OUTPUT);
  pinMode(LCD_LIGHT_PIN, INPUT);
  pinMode(ROTARY_1_PIN, INPUT_PULLUP);
  pinMode(ROTARY_2_PIN, INPUT_PULLUP);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  digitalWrite(LCD_LIGHT_PIN, LOW);

  //tell the PID to range between 0 and the full window size
  ctrl.SetOutputLimits(0, 255);
  ctrl.SetSampleTime(PID_UPDATE_INTERVAL);

  t.every(ROTARY_CHECK_INTERVAL, RotaryCheck);
  t.every(PID_UPDATE_INTERVAL, PIDUpdate);
  t.every(LCD_REDRAW_INTERVAL, LCDRedraw);
  t.every(ADC_SAMPLE_INTERVAL, ADCSample);

  display.begin();
  // init done

  // you can change the contrast around to adapt the display
  // for the best viewing!
  display.setContrast(60);

  // Initial temp
  Setpoint = 350;

  Enable();
}

// Rotary encoder with acceleration
void RotaryCheck()
{
  bool newRot = digitalRead(ROTARY_1_PIN);
  
  if (!newRot && lastRot)
  {
    if (!digitalRead(ROTARY_2_PIN))
    {
      Setpoint += accel;
      if (Setpoint > TEMP_MAX)
        Setpoint = TEMP_MAX;
    }
    else
    {
      Setpoint -= accel;
      if (Setpoint < TEMP_MIN)
        Setpoint = TEMP_MIN;
    }

    if (accel < 20)
      accel += 10;
  }
  else if (accel > 1)
    accel -= 1;

  lastRot = newRot;
}

void PIDUpdate()
{
  Input = CurrentTemp;

  double gap = abs(Setpoint-Input); //distance away from setpoint
  if (gap < 20)
    ctrl.SetTunings(consKp, consKi, consKd);
  else
    ctrl.SetTunings(aggKp, aggKi, aggKd);
  
  ctrl.Compute();

  analogWrite(CONTROL_PIN, 255-Output);
}

void LCDRedraw()
{
  display.clearDisplay();
  
  display.setTextSize(3);
  display.setTextColor(BLACK);
  display.setCursor(0,0);
  display.print(CurrentTemp, 0);
  display.setTextSize(1);
  display.println("C");

  if (Output != 0)
  {
    display.drawBitmap(68, 0, fire_bmp, 16, 21, BLACK);
  }

  display.drawRect(0, 24, 84, 4, BLACK);
  display.fillRect(1, 25, 82*(CurrentTemp/TEMP_MAX), 1, BLACK);
  display.fillRect(1, 26, 82*(Setpoint/TEMP_MAX), 1, BLACK);
  display.setCursor(0,31);
  display.print("Set: ");
  display.println(Setpoint, 0);
  display.setCursor(0,38);
  display.print("Out: ");
  display.println(Output, 0);
  
  display.display();
}

unsigned long start;

// max 5
#define ADC_MULTISAMPLING 5
#define ADC_MULTISAMPLING_SAMPLES (1 << ADC_MULTISAMPLING)

// 7.1 ms
void ADCSample()
{
  analogWrite(CONTROL_PIN, 255);
  delayMicroseconds(300);

  // Filter ADC by multisampling
  int adc = 0;
  for (int i = 0; i < ADC_MULTISAMPLING_SAMPLES; ++i)
    adc += analogRead(SENSOR_PIN);
  adc = adc >> ADC_MULTISAMPLING;

  // Apply quadratic equation to get temperature
  double temp = -0.0013*adc*adc + 1.696*adc - 59.284;
  
  // Additional temperature filtering
  CurrentTemp += (temp-CurrentTemp)*0.05;

  analogWrite(CONTROL_PIN, 255-Output);
}

void Enable()
{
  pinMode(LCD_LIGHT_PIN, OUTPUT);

  ctrl.SetMode(AUTOMATIC);

  enabled = true;
}

void Disable()
{
  pinMode(LCD_LIGHT_PIN, INPUT);

  ctrl.SetMode(MANUAL);
  Output = 0;

  enabled = false;
}

void loop() {
  t.update();
  btn.read();

  if (btn.wasPressed())
  {
    if (enabled)
      Disable();
    else
      Enable();
  }
}

Libraries used:

• https://github.com/JChristensen/Timer
• https://github.com/JChristensen/JC_Button
• https://github.com/br3ttb/Arduino-PID-Library
• Adafruit GFX and PCD8544 libraries from arduino repository

EDIT 5/21/2018:

JChristensen/Button library was renamed to JC_Button. Source code and links updated.